グローバルメニューなどで、シーン移動時にアクションがある場合、直リンでアクセスされたときにメニューが全然動かない状態になった。
そんなときの Progression 4 での到着シーンのID取得方法。

[ IndexScene.as ]

// 下記を追加する
/**
 * シーン移動時に目的地がシーンオブジェクトの子階層であり、かつ出発地ではない場合に、自身が移動を中継した瞬間に送出されます。
 * このイベント処理の実行中には、ExecutorObject を使用した非同期処理が行えます。
 */
override protected function atSceneDescend():void {
	if( manager.destinedSceneId.toString() == "/index/scene_a" ) {
		// scene_a の場合の処理
	} else if( manager.destinedSceneId.toString() == "/index/scene_b" ) {
		// scene_b の場合の処理
	} else if( manager.destinedSceneId.toString() == "/index/scene_c" ) {
		// scene_c の場合の処理
	}

	addCommand(
		// なにか処理する場合はここに記述
	);
}

っと、atSceneDescend() でいきなり子シーンにアクセルするときのイベントを取得できるので、
このときに、manager.destinedSceneIdでシーンのnameで設定しておいたString型がとれる。
それに応じて処理を変えていく。

SceneObjectクラスにそーゆーのがあるかと思ってずっと探してたら、Progressionクラスにありました。なるほど、管理してるクラスに任せるのは理にかなってる、さすがです。

—
[追記]
間違えました（と言うか、付け忘れてました。。）
manager.destinedSceneId は SceneId が戻り値なので、String型じゃありません。
toString() を加えるか、String型でキャストしないと等価演算子がまともに機能しませんのです。

スクロールする範囲もないので、困ったもんですなっと。

とりあえず、progression.css に下記を追加で回避。

#flashcontent {
	position    :absolute;
	left        :50%;
	top         :50%;
	width       :740px;
	height      :300px;
	line-height	:0;
	margin-left :-370px;
	margin-top  :-150px;
	overflow	:hidden;	
	}

flash の全画面表示でも今のところ問題無しなので、多分大丈夫かと。

Progression でのシーンの移動の際、通常は _onGoto() と _onInit() 内にある addCommand() の２つの処理を待つのですが、
どーしてもクロスフェードが必要になった場合の処理。
SerialList を static な変数として生成しておいて、都度アクセスするのが一番効率良いやり方らしいス。
(自分確認ではなく開発者本人がおっしゃってたので、大丈夫かと。)

やり方はいたって簡単。
IndexScene と ChildScene の _onInit と _onGoto の addCommand() での処理で静的な変数として生成した SerialList を呼ぶ。
(注：そのままだと addCommand は SerialList のためクロスフェードしないので、ParallelList にしておく必要アリ)

-IndexScene.as

public static var customCommands:SerialList = new SerialList();	// ← これ！

public var page:IndexPage;

/**
* コンストラクタ
*/
public function IndexScene() {
	addScene( new ChildScene( "child" ) );

	page = new IndexPage();
	page.alpha = 0;
}

/**
* シーンオブジェクトが目的地だった場合に、到達した瞬間に送出されます。
* このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
*/
protected override function _onInit():void {
	// 実行したいコマンドを登録します。
	addCommand(
		new ParallelList( null,
			IndexScene.customCommands,	// ← ここで実行。初回は中身が空なので何も起きませぬ。
			new SerialList( null,
				new AddChild( progression.container, page ),
				new DoTweener( page, { alpha:1, time:2 } )
			)
		),
		function():void {
			IndexScene.customCommands.clearCommand( true );		// ← クロスフェード後に中身をクリアしとく
		}
	);
}

/**
* シーンオブジェクトが出発地だった場合に、移動を開始した瞬間に送出されます。
* このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
*/
protected override function _onGoto():void {
	IndexScene.customCommands.addCommand(	// ← ここでは RemoveChild しないで、customCommands に登録だけしておく
		new DoTweener( page, { alpha:0, time:2 } ),
		new RemoveChild( progression.container, page )
	);

	// 実行したいコマンドを登録します。
	addCommand(
	);
}

下階層のシーンでも基本的に処理は一緒。

-ChildScene.as

/**
* シーンオブジェクトが目的地だった場合に、到達した瞬間に送出されます。
* このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
*/
protected override function _onInit():void {
	// 実行したいコマンドを登録します。
	addCommand(
		new ParallelList( null,
			IndexScene.customCommands,	// ← ここで実行。IndexScene の _onGoto() で設定したコマンドが同時に実行されます。
			new SerialList( null,
				new AddChild( progression.container, page ),
				new DoTweener( page, { alpha:1, time:2 } )
			)
		),
		function():void {
			IndexScene.customCommands.clearCommand( true );		// ← クロスフェード後に中身をちゃんとクリアしとく
		}
	);
}

/**
* シーンオブジェクトが出発地だった場合に、移動を開始した瞬間に送出されます。
* このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
*/
protected override function _onGoto():void {
	IndexScene.customCommands.addCommand(	// ← このページの処理を登録
		new DoTweener( page, { alpha:0, time:2 } ),
		new RemoveChild( progression.container, page )
	);

	// 実行したいコマンドを登録します。
	addCommand(
	);
}

シーンの _onGoto() では、コマンドの登録だけして、
実際の処理は、遷移先のシーンの _onInit(() で実行させるって行程です。
この処理を全部のシーンで実行させるようにしておけば、全部のページ遷移でクロスフェードになります。

基本的には AS3 の Loader() の処理と一緒っぽいです。
多分です。

例えば、子シーンで外部swf をロードする場合 : SceneObject を extends したモノ

private var sp:Sprite;
private var com:LoadChild;
private var isLoading:Boolean = false;
private var childMovieClip:MovieClip;

public function ChildScene( name:String = null, initObject:Object = null ) {
 	super( name, initObject );

	// シーン名 | タイトルの設定
	name = "childscene";
	title = "HERE IS CHILD SCENE";
}

protected override function _onLoad():void {
	// 実行したいコマンドを登録します。
	sp = new Sprite();

	var req:URLRequest = new URLRequest( "contents/swf/child.swf" );
	com = new LoadChild( sp, req );

	com.loader.onCastLoadStart = function():void {
		isLoading = true;
		this.addCommand(
			// ローディングの開始アニメーションとか
		)
	};
	com.loader.onCastLoadComplete = function():void {
		isLoading = false;
		childMovieClip = this.content;	// これで、子swf にアクセスさせて、その function を読んだり出来るようにしておきます。
		this.addCommand(
			new AddChild( progression.container, sp ),
			// ローディングの終了アニメーションとか
		);
	};
	com.addEventListener( ProgressEvent.PROGRESS, onProgress );
	// com.loader.contentLoaderInfo.addEventListener でも一緒です。
	com.execute();
}

private function onProgress( e:ProgressEvent ):void {
	var loaded:Number = com.loader.contentLoaderInfo.bytesLoaded;
	var total:Number = com.loader.contentLoaderInfo.bytesTotal;
	var percent:Number = (loaded / total);
	trace( "loading = " + percent );	// ローディング状況を trace() する
};

あとは、 childMovieClip に命令するとか、child.swf のタイムラインにアニメーション作っておくとかで
大丈夫ではないでしょうか。
もっといい方法がある気がしてならない。

そして、殴り書きのメモみたいに簡単でスイマセン。
落ち着いたら、ちゃんと。。。出来たらいいな。。。

トンでもスケジュールな案件だったので、
一球入魂するには progression しかないと思い、
思い切って使用させて頂きました。

遷移の複雑な部分を任せられる上に、各ページやその他の部分を作り込む時間がないなーっと思ってましたが、意外とあったりして、ホントに作業が楽になりました。
progression のホームページのキャッチコピーそのままです。

遥か昔の偉い人が、「神は死んだ」って言ってますが、ここに居ました。
ありがとうございました。

お惣菜屋さんのウェブサイトで、どれもこれも美味しそうなのばかりで、夜中の作業が泣きそうでした。

-
RF1 – X’mas Special Site

Client : Rock Field Co., Ltd.
Agency : amana inc.
Design : Rock Field Co., Ltd.
Flash Develop : Akari, Inc.
-

jp.progression.casts.animation.InOutMovie.as を extends するとタイムラインに作ったアニメーションを CastEvent.CAST_ADDED のタイミングで再生してくれる。
ラベル処理で再生するので、タイムラインベースみたいに作れるみたいデス。

クラス自体に
private var _inStateFrames:Array = [ "in", "stop" ];
private var _outStateFrames:Array = [ "stop", "out" ];
とあり、その下の _castAdded() での処理をみると
配列の frames[0] に移動して、 frames[i] に向かって New DoTweener() をしてるから

表示するときは、
ラベル「in」から再生、そして「stop」に来ると停止
消すときは、
ラベル「stop」から再生、そして「out」で停止

なるほど、これはラクだ！！
自分で gotoAndPlay() とか書かないで、ラベルの位置で制御できるなんて、ステキ過ぎる。

–
追記 : 08.11.21 – 18:05

ダウンロードできるサンプルだと書かれていないのだけれども、
InOutMovie は CastMovieClip を拡張したものなので、
protected override function _onCastAdded() と、
protected override function _onCastRemoved() が使用できます。
これの addCommand() でガシガシ処理しちゃえるのね。

var xml:XMLList = new XMLList(this.sceneInfo.data);
var obj:Object = XMLUtil.xmlToObject( xml );
path = obj.imageurl;

その後、それを使って URLRequest しようとしたときでした。

var req:URLRequest = new URLRequest( path );

んが、何も表示されないであります。
深度の問題かなっと思ったけれども、レイアウトに必要なものは
ほとんど new AddChildAt() で指定しているので、それはないなっと。

っで、色々 trace() を加えていたら、発見。
実ディレクトリでは「contents/images/thumbnail/***.jpg」となっているのですが、
xml には手違い（← 言い訳）で「contents/image/thumbnail/***.jpg」と記述してました・・・。

普通なら、
「Error #2044: ハンドルされていない ioError : text=Error #2035: URL が見つかりません。」
が Output で表示されるので、全然気づきませんでした。

お恥ずかしい限りです。。。

なので、こんな感じになるっということですかね。

// example code : assume TEMP as root property
var slist:SerialList = new SerialList()
slist.addCommand(
	new Trace("TEMP : " + IndexScene(root).TEMP)
)
// output - TEMP : [CLASS_NAME id="TEMP" name="instance**" group="null"]

今のとこの謎：
1. 下階層の extends CastSprite したモノから progression が参照できない。
extends SceneObject だと出来る。なんで？？
解消しました。コードは ↓

2. _onLoad() と _onInit() の違いをいまいち把握してない。
これは後に大問題になりそうな予感。。。
3. 子シーンから親シーンに戻って来たときはどーなるの？
サンプルだと行きっぱなしですね、これどーにかしないと。
4. そもそも僕のやり方は合ってるのだろうか？？
きっと人それぞれ最終的なカタチも仕様も違うから何とも言えないけど、何かもっと有り難いやり方がある気がしてならない今日この頃。

しかし、急な案件のおかげ様でじっくりやる時間が無いデス。
むー、困っーたー

—
追記 : 08.11.13 – 2:43 am

謎その1の解消コード
注：かなりの力技です。もっと良い方法がありそうなので、あんまり参考にしない方がよいかも…

まずは、IndexScene.as の CastSprite を宣言する時に引数を追加する

var temp:CastSprite = new CastSprite({prog:progression});

そして、CastSprite.as に参照させるスクリプトを記述

private var indexObject:Object;

/*======================================================================*//**
 * コンストラクタ
 */
public function CastSprite( initObject:Object = null ) {
	super( initObject );
	// indexObject に initObject の参照をコピー
	indexObject = initObject;
	trace("args : " + indexObject.prog)
}

// output - args : [Progression id="Index" group="null" sync="true"]

これで、CastSprite 内でも「indexObject.prog」は「progression」と同様に機能します。
また何かいい方法を発見したら、追記します。

が今や、只の検証用ページになりつつある。。。
一応、子シーンでの処理を追加しました。
といっても、画像が読み込まれるだけのなーんにもオモロくない感じです。

子シーンとして使っている ChildSceneObject.as がこんな風になりました。

public var bgContainer:CastSprite;

private var imgLoader:CastImageLoader;
private var scene:String;

public function ChildSceneObject( name:String = null, initObject:Object = null ) {
	super( name, initObject );
}

protected override function _onLoad():void {

	// 実行したいコマンドを登録します。
	var xml:XMLList = new XMLList(this.sceneInfo.data);
	// 現在いるシーンの名前を取得して登録
	scene = String(xml).toLowerCase();

	// 今は、背景の画像を読み込んだ後に CastSprite に AddChild しているので、それを参照
	bgContainer = new CastSprite();
	bgContainer = progression.container.getInstanceById("bgContainer") as CastSprite;

	imgLoader = new CastImageLoader();
	imgLoader.alpha = 0;
	imgLoader.addEventListener(CastEvent.CAST_LOAD_COMPLETE, loadComplete);

	// シーンの名前に該当する画像を読み込む
	addCommand(
		function():void { imgLoader.load(new URLRequest("contents/images/"+scene+".jpg")) }
	);
}

public function loadComplete( e:CastEvent ):void {

	imgLoader.removeEventListener(CastEvent.CAST_LOAD_COMPLETE, loadComplete);

	var slist:SerialList = new SerialList();
	slist.addCommand(
		new AddChild( bgContainer, imgLoader ),
		new DoTweener( imgLoader, {alpha:1, time:3, transition:"easeOutQuart"} )
	);
	slist.execute();

};

// 移動時に画像を消す
protected override function _onUnload():void {
	// 実行したいコマンドを登録します。
	addCommand (
		new DoTweener( imgLoader, {alpha:0, time:2, transition:"easeOutQuart"} ),
		new RemoveChild( bgContainer, imgLoader )
	);
}

画像を消すのは、現状は _onUnload() で処理しているけれど、 _onGoto() とどっちの方がいいのやら。
でも、これは子シーンで下階層に何も無い場合は、確実に _onUnload() の対象になるはずなので、
とりあえずは、これでいいかな。

そう言えば、前回の投稿で作ったボタンのままなのだけれど、なぜか遷移中に機能が kill されていない。。。。
おかしい、 progression のサンプルを初めて触ったときは自動で出来てたのに。
autoLock を false にした記憶はないので、どっかで間違ってる可能性大ですね。

ユーティリティクラスの StageUtils の中にある Public Method の getDocument() の使用例で下記のようになっているけど、これだと動かない気がする。

var documentRoot:Sprite = getDocument( stage );
trace( documentRoot.root == documentRoot ); // true

そもそも、ユーティリティ系のクラスは import による宣言のみで、コンストラクタを呼び出さない仕様になっているので、new 宣言が出来ないはず。
なので、使用するときは、その都度 StageUtil を頭に付けないといけないんじゃないかなーっと。

だから、多分こーすれば使えると思われまっす。

var documentRoot:Sprite = StageUtil.getDocument( stage );
trace( documentRoot.root == documentRoot ); // true